Talk:Finnish

Mielenkiintoista. Kaksi pikkupikku huomautusta vaan: sä oot kirjottanu yhteen kohtaan "paitsi" suomeksi.

Aajuu, näin muistan jossain välissä huomanneeni. Pistetääns korjaten.

Ja sitten siinä missä lukee mihin eri juttuihin ð muuttui, niin voisi mainita myös ð > j (mutta ehkä sä et laske sitä "tavallisimpien äänteiden" joukkoon?).

Qwynegold 22:42, 27 May 2009 (UTC)

Voishan noista murteista kirjoittaa paljonkin, ei ole tosin ollut kovin korkealle priorisoituna, ajattelin "sivuhaaroista" käsitellä lähisukukieliä ensin. ð → j mennee aika pitkälti ð → ∅:n alle muutenkin (hiatuksenestona).

Saa tähän artikkeliin tietysti lisäillä kaikenlaista jos haluaa.

(for English speakers: knock yourself out if you want to cover Finnish dialects or other Finnic languages) --Trɔpʏliʊm • blah 13:19, 28 May 2009 (UTC)

Ahaa, niin mä vähän ajattelinkin. Qwynegold 14:44, 6 June 2009 (UTC)

IPA Zounds

To have some real sound changes to play with, I made an IPA Zounds sc file from this article. It's not ready yet and probably very inaccurate.

Neat! I've not used IPA Zounds so I can't comment on possible formatting issues etc. The unstress'd vowel changes look like they might need conditioning however? --Trɔpʏliʊm • blah 22:02, 30 September 2009 (UTC)

That's correct, but stress (and other whole-syllable-properties) is a bit clumsy in Zounds, I'm just looking into the code, maybe I can change how that is dealt with. Then I can use more simple conditions than I would have to use now. -- Anaphory 11:54, 1 October 2009 (UTC)

Rewritten in sch, seems to work -- Anaphory 02:44, 15 October 2009 (UTC)

   #! sch
   charset utf-8
   
   -------------------------------------------------------------------------------
   -- Proto-Uralic to modern Finnic
   -- sound shift file
   -- (c) Gereon Kaiping
   -- This is not meant to be precise, it contains some strange hacks, so
   -- do not take this seriously!
   -- Source: http://wiki.frath.net/Finnish
   -------------------------------------------------------------------------------
   
   require >=1.0003
   
   package SCH::Finnish
   
   -- Lists all vowels used in any stage:
   group A
       a, ä
   group O
       o, ö
   group U
       u, ü
   group I
       i, ï
   group E
       e, ï
   
   vowel
       a, o, u,
       ä, ö, ü,
       i, e,
       ï, ï
   
   -- Lists all consonants used in any stage:
   consonant
       p, t, č, k, s, ś, δ, δʲ, w, j, l, r, m, n, ŋ, ń, lʲ, x
       m:, n:
           --
   
   group V
       {vowel}
   
   group C
       {consonant}
   
   group X
       :,i,U,C
   
   group S
       -- "sonorants"
       l, r
       w, j
   
   -------
   -- Each line gives a rule to decompose a word into syllables.
   -- Spaces on the lines separate regexps for one syllable.
   syllable basic
       C?'?VX?C?
       C?'?V X?C?C?'?VX?C?
       C?'?V X?C?C?'?V X?C?C?'?VX?C?
       C?'?V X?C?C?'?V X?C?C?'?V X?C?C?'?VX?C?
   
   -- What of the initial consonant cluster of a syllable to shift back
   -- to the previous syllable: $1 is moved to previous syllable, $2 is
   -- left in next syllable.
   syllable break
       ()(C'?V)
       (C)(C'?V)
       (X)(C'?V)
       (XC)(C'?V)
   
   -------
   -- Properties of syllables used below in the rules.
   -- Note: ^ and $ are implicit in a property, so we always match
   -- a full syllable here.
   
   property closed
       .*C#
   
   property open = !closed
   
   property stressed
       .*'.*
   
   property unstressed = !stressed
   
   ------------------------------------------------------------------------------
   -- Proto-Uralic to Pre-Finnic:
   -- [Ca. 4000 BCE to 3000 BCE]
   -- PU roots generally had the form (C)V(C)C{A I}, with initial stress; in pronouns and prepositions also CV; and two lone-V roots, the negativ verb e- and the root "self", o-.
   -- Unclear issues:
   -- the quality of the vowel *ï - [ɯ] or [ɤ]? (Substitution of Indo-Iranian *a by *ï speaks for the latter, unless these particular words are newer loans.)
   -- the quality of the vowel *a - [ɑ] or [ɒ]?
   -- was the 2nd-syllable vocalism phonemically /a i/ with fronted & backed allophones, or overtly vowel-harmonic /æ a i ɯ/?
   -- the quality of the consonant *x - [h], [x], [ɣ], something else?
   
   step "PU>PFc"
       time 500
            -- minus 4000
       rule "Loose Eng"
           ŋ > n / _#
           -- > k in the lativ ending
       rule "Dephthongization"
           iw > ü / _C
           ow > u: / _C
           -- dubious
       rule "Introduction of length"
           x > : / _C
       rule "Coda nasal simplification"
           n > 0 / _t?ś
           m > n / _(t,tś)
           m > n / _#
       rule "Stressed *ï merges with *a"
           'ï > 'a / _
       rule "Loss of /w/"
           w > 0 / ^_(o,u,ü)
       rule "Stressed Vowel Changes"
           'a: > 'o: / _
           'ä: > 'e:
       rule "Unstressed vowels"
           'V > _ / _
           a > ä / (ä,e,ï,i,ü) X? C? C _
           aw,äw > o / _
           ij > i
           iw > u
           i > e / _C
        
   ------------------------------------------------------------------------------
   -- Pre-Finnic to Proto-Finnic:
   -- [Ca. 3000 BC to 2000 BC] (likely also incomplete; this is the section of changes not shared by other branches of Uralic) 
   
   step "PFc>PtFc"
       time 1000
       -- 3000 BC to 2000 BC
       rule "Lengthening of CV"
            syllable first last
            V > V: /_#
            -- affects most old CV words with the exception of me te he se ne, which per Livonian had *-k.
       rule "Vowel changes"
            'ä > _ / _
            ä > e / _j
            a > e / '(o,u)X?C_j
               > o / '(a,e,i)X?C_j
       rule "Loss of remaining /x/"
            ixi > ö:/ _
            uxi > o:/ _
            xi > : / _
            -- (*xA, *x# apparently did not occur)
       rule "Loss of /ŋ/"
            uŋa > o: / _
            yŋä > ö: / _
            ŋi > : / (A,i,u)_
            ŋ > j / _(Cʲ, ś, č, ń)
              > _ / _k
              > w / _(U,O,C)
                  / (U,O)_
       rule "Loss of medial semivowels in i-stems"
            Uwi > U: / _
            ewi > ö: / _
            wI > i / _ 
            ji > : / (e,i,ï)_
               > j / A_#
               > j / O_
                   / U_
               > : / A_(l,r)C?'?Vi
               -- (due to [je]?)
               > i / C_#
                   / C_C
            yje > yö
       rule "Initial deaffrication. Newer initial affricates are found in loanwords and onomatopoeia."
            č > ś / #_
       rule "Remove ::"
            fix
            ::>:/_
       rule "Depalatalization, commonly attributed to Germanic superstratum influence."
            ń > ni / #C?V_V
            ń > n / _
            ʲ > 0 / _
            ś > s
       rule "Loss of /δ/"
            -- (may be gradation-related, shared with Mordvinic but not Samic. Put here to avoid requiring postulating intermediate *tʲ for the development of *ðʲ)
            δ > t 
   
   ------------------------------------------------------------------------------
   -- Proto-Finnic to Pre-Finnish:
   -- [Ca. 2000 BCE to 1000 CE]
   
   step "PtFc>PtF"
       time 2000
       -- minus 4000
       rule "Loss of /č/"
           č: > tś
           č > t
       rule "Difthong paradigm shift"
           j > i / V_C
           j > i / V_#
           w > ü / (ä,ö)_C
           w > ü / (ä,ö)_#
           w > u / (a,o)_C
           w > u / (a,o)_#
       rule "Birth of consonantal suffixes"
           i > 0 / VC_, ks_
       rule "Consonant gradation"
           syllable any, [closed]
           : > 0 / S(p, t, ts, k)_V
           p > b / S_V
           t > d
           s > z
           k > g
       rule "Suffixal gradation"
           -- (needs elaboration)
           syllable [unstressed], any
           p > b/ V_V
           t > d
           s > z
           k > b
       rule "Spirantization"
           (b,d,g) > _ / (n,m,ŋ)_
           b > β / _
           d > δ / _
           g > γ / _
       rule "Spirantization 2"
           γ > v /_
           βi > u / (a,o,u).*_#
           βi > ü / _#
           -- (3PS -Pi)
       rule "Vowel shifts 1"
           syllable unstressed
           oi > o / _
       rule "Vowel shifts 2"
           syllable stressed
           ai > ei / _
       rule "Vowel shifts 3"
           V: > V / _i
       rule "Birth of consonantal root forms"
           e > 0 / (d,t,n,s,δ)_#
           -- stem-finally after a coronal
       rule "Assibilation"
           t > s / _i
       rule "Esh-drift"
           ś > x
       rule "Assimilation"
           syllable [unstressed], any
           (k,p)t > t: / _
           xk>k:
           t?:?sn>s:
           kx > :x / _C
              > x: / _
           rn > r:
           ln > l:
           wst > st / o_ 
           (ptk)*m > m: / _
           (ptk)*st > st / _
           (ptk)*n > n: / _
       rule "Fricativ collapse, part 3"
           c > s / _#, ^_
           cs, sc > s: /_
           c > θ
           z > h
           x:? > h
       rule "V-epenthesis"
          ü,ö,o > v_ / ^_:
       rule "Shifts involving /h/"
          e > : / h_
          p,k > h / _t
   
   ------------------------------------------------------------------------------
   -- Proto-Finnic to Standard Finnish:
   -- [Ca. 1000-1900 CE] These changes are, for the most part, only attested in the Finnish-Carelian continuum.
   
   step "PtF>SF"
       time 5000
       -- [Ca. 1000-1900 CE]
       rule "Flavor"
           -- Voiced prenasal stops become geminate nasals, and (around the same time as in a whole lot of other European languages!) long mid vowels become opening difthongs:
           mb > m: / _
           nd > n: / _
           ŋg > ŋ: / _
           e: > ie
           ö: > üö
           o: > uo
       rule "Changes involving /j/"
           j > i / C_
           -- suffix-initially
       rule "More shifts with /h/"
           Vh > hV / (Vi,n,l,r)_#
           k,h > * / _#
           s > h / _l
           t > 0 / h_r
       rule "Pre-sonorant stop vocalization"
           p > u / (a,o,u).*_S
             > ü / _S
           t > _ / _(v,j)
             > u / _r(a, o)
             > ü / _r(ä, ö)
             > : / _r(i, e)
           k > : / _j
             > i / (i, e)_S(i, e)
             > u / (a, o, u)_S
             > ü / (ä, ö, ü)_S
       rule "Spirant loss"
           β > 0 / _UC
             > v / _V
           δ > _ / 'VX?_
           iδ > j / V_V
           δ > l / l_
             > r / r_
             > 0 / _
           γ > j / C_e
             > v / U_U
             > ʔ / VV_V
             > 0 / _
           h > _ / 'VX?_
             > 0 / VX?_V
       rule "Subsequent vowel changes in unstressed syllables"
           AO > A: / _
           -- or O: or U: (seemingly irregularly)
           Ae > Ai / _
           Ue > e: / _
           VU > V: / _#
           iU > U: / _
           OU > O: / _
       rule "Initial-syllable labialization"
           eü > öü / _
           e > ö / _(X)(C)Cü
           i > ü
           ie > üö
           i > ü / _wä
       rule "interdental loss"
           θ:? > ts
           δ > d
   
   ------------------------------------------------------------------------------
   -- Standard Finnish to Orthography:
   -- [Ca. 2000 CE]
   
   step "Orth"
       time 6000
       rule "long>double"
           C: > __ / _
           V: > __ / _
       rule "remove :'"
           ' > 0 / _
           : > 0 / _
       rule "different writing"
           ü > y / _
           w > v